Project:SPARQL/examples: Difference between revisions
Jump to navigation
Jump to search
No edit summary |
|||
Line 73: | Line 73: | ||
OPTIONAL { ?refnode ppsr:P23 ?statedin } | OPTIONAL { ?refnode ppsr:P23 ?statedin } | ||
} | } | ||
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } | |||
} | |||
</sparql> | |||
===Draw graph of all hosts connected to Megaira polyxenophila and their other interactions=== | |||
Megaira polyxenophila [[Item:Q141|Q141]] is an intracellular bacterium in a wide diversity of host taxa. This query includes sub-species of Megaira polyxenophila. | |||
<sparql tryit="1"> | |||
#defaultView:Graph | |||
PREFIX pp: <https://ppsdb.wikibase.cloud/entity/> | |||
PREFIX ppt: <https://ppsdb.wikibase.cloud/prop/direct/> | |||
PREFIX pps: <https://ppsdb.wikibase.cloud/prop/> | |||
PREFIX ppss: <https://ppsdb.wikibase.cloud/prop/statement/> | |||
PREFIX ppsq: <https://ppsdb.wikibase.cloud/prop/qualifier/> | |||
SELECT DISTINCT ?host ?hostLabel ?target ?linkto ?linktoLabel ?edgeLabel WHERE { | |||
?host pps:P19 ?statement. | |||
?statement ppss:P19/ppt:P29* pp:Q141 # include items with parent taxon Q141 | |||
OPTIONAL { ?statement ppsq:P20 ?edge } | |||
OPTIONAL { ?host ppt:P19 ?linkto } | |||
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } | SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". } | ||
} | } |
Revision as of 07:51, 19 March 2024
List all taxon items
PREFIX pp: <https://ppsdb.wikibase.cloud/entity/>
PREFIX ppt: <https://ppsdb.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel WHERE {
?item ppt:P18 pp:Q2.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
List all interaction types and RO mapping if available
PREFIX pp: <https://ppsdb.wikibase.cloud/entity/>
PREFIX ppt: <https://ppsdb.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?roterm WHERE {
?item ppt:P18 pp:Q1.
OPTIONAL {
?item ppt:P16 ?roterm
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
List all body parts and GO mapping if available
PREFIX pp: <https://ppsdb.wikibase.cloud/entity/>
PREFIX ppt: <https://ppsdb.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?goterm WHERE {
?item ppt:P18 pp:Q5.
OPTIONAL {
?item ppt:P17 ?goterm
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
List all analytical techniques and Wikidata mapping if available
PREFIX pp: <https://ppsdb.wikibase.cloud/entity/>
PREFIX ppt: <https://ppsdb.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?itemLabel ?wikidata WHERE {
?item ppt:P18 pp:Q6.
OPTIONAL {
?item ppt:P2 ?wikidata
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
List all interactions, optionally the localization, interaction type, and references
PREFIX pp: <https://ppsdb.wikibase.cloud/entity/>
PREFIX ppt: <https://ppsdb.wikibase.cloud/prop/direct/>
PREFIX pps: <https://ppsdb.wikibase.cloud/prop/>
PREFIX ppss: <https://ppsdb.wikibase.cloud/prop/statement/>
PREFIX ppsq: <https://ppsdb.wikibase.cloud/prop/qualifier/>
PREFIX ppsr: <https://ppsdb.wikibase.cloud/prop/reference/>
SELECT DISTINCT ?host ?hostLabel ?typeLabel ?symbiontLabel ?localizationLabel ?doi ?statedin WHERE {
?host pps:P19 ?interaction.
?interaction ppss:P19 ?symbiont.
OPTIONAL { ?interaction ppsq:P20 ?localization. }
OPTIONAL { ?interaction ppsq:P26 ?type. }
OPTIONAL {
?interaction prov:wasDerivedFrom ?refnode.
OPTIONAL { ?refnode ppsr:P27 ?doi }
OPTIONAL { ?refnode ppsr:P23 ?statedin }
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Draw graph of all hosts connected to Megaira polyxenophila and their other interactions
Megaira polyxenophila Q141 is an intracellular bacterium in a wide diversity of host taxa. This query includes sub-species of Megaira polyxenophila.
#defaultView:Graph
PREFIX pp: <https://ppsdb.wikibase.cloud/entity/>
PREFIX ppt: <https://ppsdb.wikibase.cloud/prop/direct/>
PREFIX pps: <https://ppsdb.wikibase.cloud/prop/>
PREFIX ppss: <https://ppsdb.wikibase.cloud/prop/statement/>
PREFIX ppsq: <https://ppsdb.wikibase.cloud/prop/qualifier/>
SELECT DISTINCT ?host ?hostLabel ?target ?linkto ?linktoLabel ?edgeLabel WHERE {
?host pps:P19 ?statement.
?statement ppss:P19/ppt:P29* pp:Q141 # include items with parent taxon Q141
OPTIONAL { ?statement ppsq:P20 ?edge }
OPTIONAL { ?host ppt:P19 ?linkto }
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Maintenance queries
Generate QuickStatements to add "instance of: taxon" to items with NCBI taxon IDs
PREFIX pp: <https://ppsdb.wikibase.cloud/entity/>
PREFIX ppt: <https://ppsdb.wikibase.cloud/prop/direct/>
PREFIX pps: <https://ppsdb.wikibase.cloud/prop/>
PREFIX ppss: <https://ppsdb.wikibase.cloud/prop/statement/>
PREFIX ppsq: <https://ppsdb.wikibase.cloud/prop/qualifier/>
SELECT DISTINCT ?qid ?P18 WHERE {
?host pps:P19 ?symbiont.
FILTER NOT EXISTS {
?host ppt:P18 ?instanceof.
?instanceof ppt:P24* pp:Q2
}
?host ppt:P11 ?ncbi
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
BIND (ENCODE_FOR_URI(REPLACE(STR(?host), ".*Q", "Q")) AS ?qid) # article item
BIND ("Q2" AS ?P18)
}
List all classes
PREFIX ppt: <https://ppsdb.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?class ?classLabel WHERE {
?item ppt:P18 ?class
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Taxon items without parent taxon
PREFIX pp: <https://ppsdb.wikibase.cloud/entity/>
PREFIX ppt: <https://ppsdb.wikibase.cloud/prop/direct/>
SELECT DISTINCT ?item ?qid ?itemLabel WHERE {
?item ppt:P18 pp:Q2.
FILTER NOT EXISTS {
?item ppt:P29 ?parent.
}
BIND (ENCODE_FOR_URI(REPLACE(STR(?item), ".*Q", "Q")) AS ?qid)
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
}
Statistics
Count interactions per host taxon, report in descending order
Treat these counts with a pinch of salt, because species concepts differ.
PREFIX ppt: <https://ppsdb.wikibase.cloud/prop/direct/>
SELECT ?host ?hostLabel (COUNT (DISTINCT ?symbiont) AS ?count) WHERE {
?host ppt:P19 ?symbiont.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?host ?hostLabel ORDER BY DESC(?count)
Count interactions per symbiont taxon, report in descending order
PREFIX ppt: <https://ppsdb.wikibase.cloud/prop/direct/>
SELECT ?symbiont ?symbiontLabel (COUNT (DISTINCT ?host) AS ?count) WHERE {
?host ppt:P19 ?symbiont.
SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],en". }
} GROUP BY ?symbiont ?symbiontLabel ORDER BY DESC(?count)